Opisując funkcję JEŻELI wspominałem, że pierwszy argument tej funkcji to jest test logiczny. Czyli pytanie. Przykładowo: aby uczeń uzyskał zaliczenie z przedmiotu musi uzyskać minimum 40 punktów. Oto klasyczna funkcja JEŻELI:

No dobra, ale sytuacja się nieco komplikuje, gdy uzyskanie zaliczenia wymaga spełnienia np. dwóch warunków. Wewnątrz funkcji JEŻELI możemy „zadać tylko jedno pytanie”. Tutaj z pomocą nam przychodzą funkcje: ORAZ i LUB.
Pobierz skoroszyt zawierający ćwiczenia
Funkcja ORAZ
Funkcja ORAZ zwraca wartość PRAWDA wtedy, gdy wszystkie argumenty zwracają wartość PRAWDA (czyli odpowiedź na wszystkie pytania jest twierdząca). Jeśli choć jeden argument funkcji ORAZ zwróci wartość FAŁSZ, to funkcja zwróci wartość FAŁSZ.

Aby uzyskać zaliczenie z przedmiotu uczeń musi spełnić jednocześnie dwa warunki: uzyskać z zaliczenia minimum 40 punktów, oraz mieć minimum 10 obecności. Możemy te dwa warunki zapisać wewnątrz funkcji ORAZ
=ORAZ(D2>=40; E2>=10)
Jeśli dany uczeń spełni oba te warunki, to pojawi się wartość PRAWDA.

Jeśli chcesz, aby Excel zamiast PRAWDA/FAŁSZ wyświetlił Twój tekst (np. Zdał, Oblał) to należy funkcję ORAZ wsadzić do funkcji JEŻELI:
=JEŻELI(ORAZ(D2>=40; E2>=10)=PRAWDA; "Zdał"; "Oblał")
Możemy też nieco skrócić ten zapis (wyrażenie =PRAWDA jest opcjonalne)
=JEŻELI(ORAZ(D2>=40; E2>=10); "Zdał"; "Oblał")

Oczywiście moglibyśmy tutaj użyć zagnieżdżonej funkcji JEŻELI, ale szczerze mówiąc nie wygląda to za dobrze:
=JEŻELI(D2>=40; JEŻELI(E2>=10; "Zdał"; "Oblał"); "Oblał")
A co jeśli jest więcej warunków? Otóż wewnątrz funkcji ORAZ możemy wpisać 255 warunków. To pewnie zdecydowanie więcej niż potrzebujemy, ale rozpatrzmy inny przykład.

Tutaj będą aż trzy warunki, które należy spełnić, aby uzyskać zaliczenie:
- Należy uzyskać minimum 40 punktów
- Należy mieć minimum 10 obecności
- Należy odbyć staż
Więc nasza funkcja ORAZ będzie wyglądała następująco:
=ORAZ(D2>=40; E2>=10; F2="tak")
Jeśli uczeń nie spełni choćby jednego z tych trzech warunków, to nie otrzyma zaliczenia.
Funkcja LUB
Funkcja LUB działa dość podobnie do funkcji ORAZ. Jedyna różnica jest taka, że funkcja LUB zwraca wartość prawda gdy przynajmniej jeden warunek jest spełniony. Np. uczeń może uzyskać zaliczenie gdy zdobędzie z testu odpowiednią liczbę punktów, lub gdy otrzyma nagrodę ministra

Tak wygląda nasza formuła:
=LUB(D2>=40; E2="tak")
Oczywiście jak najbardziej możemy funkcję LUB opakować funkcją JEŻELI
=JEŻELI(LUB(D2>=40;E2="tak"); "Zdał"; "Nie zdał")
Przedziały liczbowe, zagnieżdżanie funkcji LUB i ORAZ

Funkcja LUB świetnie się sprawdza, gdy mamy rozłączne przedziały. Np. z wsparcia mogą skorzystać tylko osoby do 30 roku życia (włącznie) lub od 50 roku życia. Możemy napisać taką formułę:
=LUB(D2<=30;D2>=50)
Z kolei jeśli chcielibyśmy oferować wsparcie osobom pomiędzy 30 a 50 rokiem życia to tutaj użyjemy funkcji ORAZ gdyż muszą być spełnione jednocześnie dwa warunki: osoba musi mieć więcej niż 30 lat i jednocześnie mniej niż 50:
=ORAZ(D2>30; D2<50)
No a teraz pojedziemy po bandzie. Załóżmy, że nas interesują osoby z dwóch przedziałów wiekowych tj. 20-30 lat lub 40-50 lat. Tutaj będzie użyta funkcja LUB której argumentami będą dwie funkcje ORAZ.
Może zacznijmy od czegoś prostszego:
ORAZ(D2>=20; D2<=30)
ORAZ(D2>=40; D2<=50)
Te dwie funkcje zwrócą nam wartość prawda, gdy wiek danej osoby jest w pożądanym przez nas przedziale. Ponieważ interesują nas osoby, które spełniają jeden z dwóch podanych powyżej warunków, to należy owe funkcje ORAZ wsadzić do funkcji LUB:
=LUB(ORAZ(D2>=20; D2<=30); ORAZ(D2>=40; D2<=50))
Oczywiście jeśli byśmy chcieli, to możemy to wszystko opakować funkcją JEŻELI:
=JEŻELI(LUB(ORAZ(D2>=20; D2<=30); ORAZ(D2>=40; D2<=50)); "Zakwalifikowany"; "Niezakwalifikowany")

Tutaj mamy dość podobne zadanie. Do projektu są zakwalifikowane osoby młode z wykształceniem podstawowym, lub osoby 50+ (tu już nie ma drugiego kryterium dotyczącego wykształcenia). Tak więc użyję tutaj funkcji LUB gdzie pierwszym argumentem będzie funkcja ORAZ z warunkiem wieku do trzydziestki i wykształcenie podstawowe; a drugi argument funkcji LUB to będzie pytanie o wiek po pięćdziesiątce. W efekcie wychodzi taka oto formuła:
=LUB(ORAZ(D2>=30;E2="podstawowe"); D2>50)
Jak widzisz funkcje LUB i ORAZ mogą zwiększyć możliwości funkcji JEŻELI.