Funkcja LICZ.JEŻELI i symbole wieloznaczne * i ?

Pobierz przykładowy plik z zadaniami z tego wpisu.

Załóżmy, że mamy taką oto prostą bazę klientów:

Za pomocą funkcji LICZ.JEŻELI możemy policzyć ile komórek w danym zakresie spełnia jakiś warunek. W poprzednim wpisie opisywałem proste warunki np. jeśli chciałbym policzyć ile mamy osób o imieniu Robert to funkcja będzie wyglądała następująco:

=LICZ.JEŻELI(A2:A14; "Robert")

 Owa funkcja jest bardzo przydatna, ale ma pewne ograniczenia. Przykładowo chcąc policzyć ile mamy osób, których imiona zaczynają się na literę M musimy skorzystać z symboli wieloznacznych. Być może z nimi wcześniej się spotkałeś w innych programach (np. w wyszukiwarkach plików). W Excelu w funkcjach wyszukujących można skorzystać z dwóch symboli wieloznacznych: gwiazdki i pytajnika

  • ? – oznacza jeden dowolny znak (Excel zamiast pytajnika podstawia we wzorcu wyszukiwania dowolny znak)
  • * – oznacza dowolny ciąg znaków (Excel zamiast gwiazdki podstawia dowolny ciąg znaków, ciąg ten może być pusty)

Być może zabrzmiało to bardzo naukowo, ale myślę, że kilkanaście poniższych przykładów dobrze zobrazuje to zagadnienie.

Aby policzyć ile mamy osób, których imię zaczyna się na literę M w drugim argumencie funkcji należy wpisać M* (czyli imię musi się zaczynać na literę M a gwiazdka mówi, że potem może być „cokolwiek”).

=LICZ.JEŻELI(A2:A14; "M*")

Funkcja zwróci wynik 4, gdyż mamy trzech Michałów i jedną Magdalenę.

A teraz policzmy ile mamy imion, które nie zaczynają się na literę M. Tutaj formuła będzie podobna, z tym, że dodatkowo trzeba użyć operatora <> (różne od)

=LICZ.JEŻELI(A2:A14; "<>M*")

Funkcja zwróciła nam wynik 9. I wszystko się zgadza, gdyż na liście osób mamy w sumie 13 nazwisk

Teraz policzmy ile mamy kobiet. Jak zapewne wiesz polskojęzyczne damskie imiona kończą się na literę a. Natomiast męskie imiona kończą się na dowolną literę, tylko nie na a (tutaj mamy kilka wyjątków jak np. Kuba, Barnaba, Bonawentura, Kosma, Dyzma i Juda, ale aby nie komplikować ćwiczenia nie będziemy uwzględniać tych wyjątków). Czyli w celu policzenia kobiet użyjemy taką oto funkcję (gwiazdka mówi, że może być cokolwiek a na końcu litera a mówi, że ciąg znaków musi się kończyć na literę a).

=LICZ.JEŻELI(A2:A14; "*a")

W celu policzenia mężczyzn użyjemy należy w kryteriach dodać operator różne od czyli „dwa dziubki”:

=LICZ.JEŻELI(A2:A14;"<>*a")

Pytajnik oznacza, że mamy na myśli dokładnie jeden dowolny znak. Chcąc znaleźć dowolne trzyliterowe nazwiska, które zaczynają się na literę K i kończą się na literę t użyjemy takiej oto funkcji:

=LICZ.JEŻELI(B2:B14;"K?t")

W wyniku Excel nam zwróci liczbę 3 (do wzorca K?t pasują nazwiska: Kat, Kot, Kit, ale np. nazwisko Krawat już nie pasuje, gdyż pomiędzy literami K i t jest więcej niż jedna litera)

Jeśli chcemy policzyć ile mamy nazwisk „o dowolnej” długości, które zaczynają się na literę K i kończą na literę t użyjemy należy wpisać taką oto formułę:

=LICZ.JEŻELI(B2:B14;"K*t")

Tutaj oprócz nazwisk Kat, Kot, Kit będą pasowały nazwiska Krawat, Karat oraz dwuliterowe nazwisko Kt (gwiazdka oznacza dowolny ciąg znaków znajdujący się pomiędzy literami K i t, ale ten ciąg znaków może być pusty)

Jeśli chcemy policzyć ile mamy nazwisk trzyliterowych, które jako drugą literę mamy literę o to należy wpisać taką formułę (jeden dowolny znak, litera o, jeden dowolny znak):

=LICZ.JEŻELI(B2:B14;"?o?")

Aby policzyć imiona, które jako drugą literę mamy a należy wpisać taką funkcję (jeden dowolny znak, a, dowolny ciąg znaków)

=LICZ.JEŻELI(A2:A14; "?a*")

Aby policzyć imiona, które jako trzecią literę mają k należy wpisać taką funkcje (jeden dowolny znak, jeden dowolny znak, k, dowolny ciąg znaków)

=LICZ.JEŻELI(A2:A14; "??k*")

Aby policzyć imiona, które jako przedostatnią literę mają r należy wpisać taką oto funkcję (dowolny ciąg znaków, r, dowolny jeden znak):

=LICZ.JEŻELI(A2:A14; "*r?")

Do wzorca pasują imiona Barbara i dwa razy Robert

Aby policzyć imiona, które jako trzecią od końca literę mają z należy wpisać taką funkcję (dowolny ciąg znaków, z, dowolny znak, dowolny znak):

=LICZ.JEŻELI(A2:A14; "*z??")

Tutaj do wzorca pasuje nam Andrzej i Agnieszka

LICZ.WARUNKI

Funkcja LICZ.JEŻELI zlicza tylko te komórki, które spełniają jedno kryterium. Jeśli chcemy policzyć komórki, które spełniają kilka kryteriów należy skorzystać z funkcji LICZ.WARUNKI którą niedawno opisałem na blogu. W tej funkcji również można stosować symbole wieloznaczne. Tym razem nas interesują te osoby, które są kobietami (pierwszy warunek) i nazwisko zaczyna się na literę K (drugi warunek). W tym celu należy wpisać taką oto formułę:

=LICZ.WARUNKI(A2:A14; "*a"; B2:B14; "K*")

Funkcja zwróci wartość 1, gdyż jednocześnie te dwa warunki spełnia tylko Magdalena Krawat.

Ten wpis został opublikowany w kategorii funkcje i oznaczony tagami , , , , . Dodaj zakładkę do bezpośredniego odnośnika.

Dodaj komentarz

Twój adres email nie zostanie opublikowany. Pola, których wypełnienie jest wymagane, są oznaczone symbolem *

Witryna wykorzystuje Akismet, aby ograniczyć spam. Dowiedz się więcej jak przetwarzane są dane komentarzy.